Access911.net   |   a9BBS   |   OTaA System  
  搜索文章:  
Access911欢迎您光临  
   主页      上传      繁體版       论坛     
设为首页  |  加入收藏   
  
你现在的位置:文章索引 -> 文章分类 -> VBA  
 首页|  近日更新|  下载  |  文章索引  |  搜索|  术语|  承接工程|  
 
系统正在加载内容,请耐心等待...
 
 查询
 窗体
 报表
 
 
 VBA
 函数
 ADO/DAO/ADO.NET
 API
 ADP
 安全
 发布
 OA
 ASP/ASP.NET
 其他语言
 控件
 DELPHI
 C#/.Net
 本站
 其他
 小例程
 常用软件
 参考文档
 业主作品
 网友大作
 
 
友情链接
 access911.net
 
访问人次
 1702699
 
站长 E-Mail
 net911@sina.com
 access911@gmail.com
 
RSS 订阅

显示附加信息 >>>

如何引用/打开外部数据库的窗体?

作者:cg1  摘自:access911.net  :cg1  更新日期:2003-1-4  浏览人次:

 

方法一:

方法很多,请不要局限于下面的代码:

'引用外部数据库的窗体
'************ Code Start *************
Private Declare Function apiSetForegroundWindow Lib "user32" _
Alias "SetForegroundWindow" _
(ByVal hwnd As Long) _
As Long

Private Declare Function apiShowWindow Lib "user32" _
Alias "ShowWindow" _
(ByVal hwnd As Long, _
ByVal nCmdShow As Long) _
As Long

Private Const SW_MAXIMIZE = 3
Private Const SW_NORMAL = 1

Function fOpenRemoteForm(strMDB As String, _
strForm As String, _
Optional intView As Variant) _
As Boolean

Dim objAccess As Access.Application
Dim lngRet As Long

On Error GoTo fOpenRemoteForm_Err

    If IsMissing(intView) Then intView = acViewNormal

        If Len(Dir(strMDB)) > 0 Then
            Set objAccess = New Access.Application
            With objAccess
                lngRet = apiSetForegroundWindow(.hWndAccessApp)
                lngRet = apiShowWindow(.hWndAccessApp, SW_NORMAL)
                'the first call to ShowWindow doesn't seem to do anything
                lngRet = apiShowWindow(.hWndAccessApp, SW_NORMAL)
                .OpenCurrentDatabase strMDB
                .DoCmd.OpenForm strForm, intView
                Do While Len(.CurrentDb.name) > 0
                    DoEvents
                Loop
            End With
        End If

fOpenRemoteForm_Exit:
On Error Resume Next
    objAccess.Quit
    Set objAccess = Nothing
    Exit Function
fOpenRemoteForm_Err:
    fOpenRemoteForm = False
    Select Case Err.Number
        Case 7866:
            'mdb is already exclusively opened
            MsgBox "The database you specified " & vbCrLf & strMDB & _
                    vbCrLf & "is currently open in exclusive mode. " & vbCrLf _
                    & vbCrLf & "Please reopen in shared mode and try again", _
                    vbExclamation + vbOKOnly, "Could not open database."
        Case 2102:
            'form doesn't exist
            MsgBox "The Form '" & strForm & _
                    "' doesn't exist in the Database " _
                    & vbCrLf & strMDB, _
                    vbExclamation + vbOKOnly, "Form not found"
        Case 7952:
            'user closed mdb
            fOpenRemoteForm = True
        Case Else:
            'MsgBox "Error#: " & Err.Number & vbCrLf & Err.Description, _
                    vbCritical + vbOKOnly, "Runtime error"
    End Select
Resume fOpenRemoteForm_Exit
End Function

Private Sub 命令0_Click()
    fOpenRemoteForm CurrentProject.path & "\ftpdown.mdb", "窗体2"
End Sub

其实就是以隐藏的方式打开一个 ACCESS 应用程序,然后再用 ACCESS.APPLICATION.DOCMD.OPENFORM

 

方法二:

在原先那个数据库A,窗体在A数据库中,在A里面新建一个模块,写一个公共函数,函数中包含打开窗体的代码。在当前的数据库B中引用该数据库,然后执行原先数据库A的函数即可。
http://access911.net/down/eg/eg_References2.rar
 (20KB)

可参考讨论
调用其他数据库窗体无法读取当前数据库的数据
http://bbs.bbezone.com/viewthread.php?tid=191&extra=page%3D1

 

 

 
相关文章
     没有手动相关文章
     如何编程打开其他数据库中的窗体?
     如何查询其他数据库内的表(IN子句实例)?
 
评论
     查看或发表更多的评论,请单击这里。
 
 
 
 
 
   
  Access911.net   |   a9BBS   |   OTaA System   |
建站日期:2000年4月2日  |  设计施工:陈格 ( access911 & cg1 )
 Copyright © 2000 - 2003 COMET, 陈格 保留所有权利