Access911.net   |   a9BBS   |   OTaA System  
  搜索文章:  
Access911欢迎您光临  
   主页      上传      繁體版       论坛     
设为首页  |  加入收藏   
  
你现在的位置:文章索引 -> 文章分类 -> API  
 首页|  近日更新|  下载  |  文章索引  |  搜索|  术语|  承接工程|  
 
系统正在加载内容,请耐心等待...
 
 查询
 窗体
 报表
 
 
 VBA
 函数
 ADO/DAO/ADO.NET
 API
 ADP
 安全
 发布
 OA
 ASP/ASP.NET
 其他语言
 控件
 DELPHI
 C#/.Net
 本站
 其他
 小例程
 常用软件
 参考文档
 业主作品
 网友大作
 
 
友情链接
 access911.net
 
访问人次
 1702743
 
站长 E-Mail
 net911@sina.com
 access911@gmail.com
 
RSS 订阅

显示附加信息 >>>

如何检测Internet联网状态、类型及拨号网络调用?

作者:未详  摘自:未详  :cg1  更新日期:2002-12-12  浏览人次:

 

方法一:

以下代码摘自 http://klhome.vicp.net ——一个新开的office论坛,希望大家多去捧场

在模块中输入以下代码:
Option Compare Database
'检测Intenet连接
Public Declare Function InternetGetConnectedStateEx Lib "wininet.dll" _
    Alias "InternetGetConnectedStateExA" _
    (ByRef lpdwFlags As Long, _
    ByVal lpszConnectionName As String, _
    ByVal dwNameLen As Long, _
    ByVal dwReserved As Long _
    ) As Long

Public Enum EIGCInternetConnectionState
    INTERNET_CONNECTION_MODEM = &H1&
    INTERNET_CONNECTION_LAN = &H2&
    INTERNET_CONNECTION_PROXY = &H4&
    INTERNET_RAS_INSTALLED = &H10&
    INTERNET_CONNECTION_OFFLINE = &H20&
    INTERNET_CONNECTION_CONFIGURED = &H40&
End Enum


Public Property Get InternetConnected( _
    Optional ByRef eConnectionInfo As EIGCInternetConnectionState, _
    Optional ByRef sConnectionName As String _
    ) As Boolean
    Dim dwFlags As Long
    Dim sNameBuf As String
    Dim lR As Long
    Dim iPos As Long
    
    sNameBuf = String$(513, 0)
    lR = InternetGetConnectedStateEx(dwFlags, sNameBuf, 512, 0&)
    eConnectionInfo = dwFlags
    iPos = InStr(sNameBuf, vbNullChar)
    If iPos > 0 Then
        sConnectionName = Left$(sNameBuf, iPos - 1)
    ElseIf Not sNameBuf = String$(513, 0) Then
        sConnectionName = sNameBuf
    End If
    InternetConnected = (lR = 1)
End Property


----------------------------------------------------

建立一个窗体,输入以下代码:
Option Compare Database

Dim eR As EIGCInternetConnectionState
Dim sMsg As String
Dim sName As String
Dim bConnected As Boolean

'调用已建立的拨号及断开连接
'*****************************************************************
Const INTERNET_DIALSTATE_DISCONNECTED = 1
Const INTERNET_AUTODIAL_FORCE_ONLINE = 1
Const INTERNET_AUTODIAL_FORCE_UNATTENDED = 2
Const INTERNET_DIAL_UNATTENDED = &H8000

Dim iHandle As Long

Private Declare Function InternetDial Lib "wininet.dll" ( _
    ByVal hwndParent As Long, _
    ByVal lpszConnectoid As String, _
    ByVal dwFlags As Long, _
    lpdwConnection As Long, _
    ByVal dwReserved As Long) As Long
    
'参数dwConnection指定拨号连接句柄
Private Declare Function InternetHangUp Lib "wininet.dll" _
    (ByVal dwConnection As Long, _
    ByVal dwReserved As Long) As Long
    
Private Declare Function InternetAutodial Lib "wininet.dll" _
        (ByVal dwFlags As Long, ByVal dwReserved As Long) As Long
        
Private Declare Function InternetAutodialHangup Lib "wininet.dll" _
        (ByVal dwReserved As Long) As Long
'*****************************************************************

Private Sub Form_Load()
    DoCmd.RunCommand acCmdAppMinimize
    DoCmd.Restore
    ' Determine whether we have a connection:
    bConnected = InternetConnected(eR, sName)

    ' The connection state info parameter provides details
    ' about how we connect:
    If (eR And INTERNET_CONNECTION_MODEM) = INTERNET_CONNECTION_MODEM Then
        sMsg = sMsg & "Connection uses a modem." & vbCrLf
    End If
    If (eR And INTERNET_CONNECTION_LAN) = INTERNET_CONNECTION_LAN Then
        sMsg = sMsg & "Connection uses LAN." & vbCrLf
    End If
    If (eR And INTERNET_CONNECTION_PROXY) = INTERNET_CONNECTION_PROXY Then
        sMsg = sMsg & "Connection is via Proxy." & vbCrLf
    End If
    If (eR And INTERNET_CONNECTION_OFFLINE) = INTERNET_CONNECTION_OFFLINE Then
        sMsg = sMsg & "Connection is Off-line." & vbCrLf
    End If
    If (eR And INTERNET_CONNECTION_CONFIGURED) = INTERNET_CONNECTION_CONFIGURED Then
        sMsg = sMsg & "Connection is Configured." & vbCrLf
    Else
        sMsg = sMsg & "Connection is Not Configured." & vbCrLf
    End If
    If (eR And INTERNET_RAS_INSTALLED) = INTERNET_RAS_INSTALLED Then
        sMsg = sMsg & "System has RAS installed." & vbCrLf
    End If
   
   ' Display the connection name and info:
    If bConnected Then
        标签0.Caption = "Connected: " & sName & vbCrLf & vbCrLf & sMsg
    Else
        标签0.Caption = "Not Connected: " & vbCrLf & vbCrLf & sMsg
    End If
End Sub
Private Sub 拨号_Click()
    '“连接到 96333”是我电脑里的一个拨号连接的名称,你可把它改成你自已建立的拨号连接的名称
    'InternetDial Me.hwnd, "连接到 96333", INTERNET_AUTODIAL_FORCE_UNATTENDED, iHandle, 0
    
    '动态查找拨号连接,并自动调用它,你电脑里要建立了拨号连接才能使用
    InternetDial Me.hwnd, sName, INTERNET_AUTODIAL_FORCE_UNATTENDED, iHandle, 0
    Form_Load
End Sub

Private Sub 断开_Click()
    标签0.Caption = "正在断开连接,请稍候…"
    DoEvents
    If iHandle <> 0 Then
        InternetHangUp iHandle, 0
        iHandle = 0
    End If
    Form_Load
End Sub


 


方法二:

拨号、断网、枚举连接名称,判断是否在线、连接方式。

http://blog.csdn.net/Modest/archive/2006/10/20/1342633.aspx


(声明:魏滔序原创,转贴请注明出处。) 
Option Explicit
'拨号/断网
Private Declare Function InternetDial Lib "wininet.dll" (ByVal hwndParent As Long, ByVal lpszConnectoid As String, ByVal dwFlags As Long, lpdwConnection As Long, ByVal dwReserved As Long) As Long
Private Declare Function InternetHangUp Lib "wininet.dll" (ByVal dwConnection As Long, ByVal dwReserved As Long) As Long
Private Declare Function InternetAutodial Lib "wininet.dll" (ByVal dwFlags As Long, ByVal dwReserved As Long) As Long
Private Declare Function InternetAutodialHangup Lib "wininet.dll" (ByVal dwReserved As Long) As Long
Private Const INTERNET_DIALSTATE_DISCONNECTED = 1
Private Const INTERNET_AUTODIAL_FORCE_ONLINE = 1
Private Const INTERNET_AUTODIAL_FORCE_UNATTENDED = 2
Private Const INTERNET_DIAL_UNATTENDED = &H8000
Private Handle As Long

'网络状态
Private Declare Function InternetGetConnectedStateEx Lib "wininet.dll" Alias "InternetGetConnectedStateExA" (ByRef lpdwFlags As Long, ByVal lpszConnectionName As String, ByVal dwNameLen As Long, ByVal dwReserved As Long) As Long
Private Declare Function InternetGetConnectedState Lib "wininet.dll" (ByRef dwFlags As Long, ByVal dwReserved As Long) As Long
Private Const INTERNET_CONNECTION_MODEM As Long = &H1      '本系统使用调制解调器与因特网相连
Private Const INTERNET_CONNECTION_LAN As Long = &H2        '本系统通过LAN与因特网相连
Private Const INTERNET_CONNECTION_PROXY As Long = &H4      '本系统使用proxy代理服务器与因特网相连
Private Const INTERNET_CONNECTION_MODEM_BUSY As Long = &H8 '未使用
Private Const INTERNET_RAS_INSTALLED As Long = &H10
Private Const INTERNET_CONNECTION_OFFLINE As Long = &H20
Private Const INTERNET_CONNECTION_CONFIGURED As Long = &H40

'枚举网络连接
Private Const RAS_MaxDeviceType = 16
Private Const RAS95_MaxDeviceName = 128
Private Const RAS95_MaxEntryName = 256
Private Type RASCONN95
    dwSize As Long
    hRasConn As Long
    szEntryName(RAS95_MaxEntryName) As Byte
    szDeviceType(RAS_MaxDeviceType) As Byte
    szDeviceName(RAS95_MaxDeviceName) As Byte
End Type
Private Type RASENTRYNAME95
    dwSize As Long
    szEntryName(RAS95_MaxEntryName) As Byte
End Type
Private Declare Function RasEnumConnections Lib "rasapi32.dll" Alias "RasEnumConnectionsA" (lprasconn As Any, lpcb As Long, lpcConnections As Long) As Long
Private Declare Function RasEnumEntries Lib "rasapi32.dll" Alias "RasEnumEntriesA" (ByVal reserved As String, ByVal lpszPhonebook As String, lprasentryname As Any, lpcb As Long, lpcEntries As Long) As Long
Private Declare Function RasHangUp Lib "rasapi32.dll" Alias "RasHangUpA" (ByVal hRasConn As Long) As Long

'拨号
Public Function DialUp(LinkName As String) As Boolean
    InternetDial 0, LinkName, INTERNET_AUTODIAL_FORCE_UNATTENDED, Handle, 0
    DialUp = (Handle <> 0)
End Function
'断网
Public Sub HangUp()
    If Handle <> 0 Then
        InternetHangUp Handle, 0
        Handle = 0
    End If
End Sub


'枚举网络连接
Public Sub EnumConnectName(Value() As String)
    Dim s As Long, l As Long, ln As Long, a As String
    ReDim r(255) As RASENTRYNAME95

    r(0).dwSize = 264
    s = 256 * r(0).dwSize
    l = RasEnumEntries(vbNullString, vbNullString, r(0), s, ln)
    ReDim Value(ln - 1)
    For l = 0 To ln - 1
        a = StrConv(r(l).szEntryName(), vbUnicode)
        Value(l) = Left$(a$, InStr(a$, Chr$(0)) - 1)
    Next
End Sub

'判断是否在线
Public Function Online() As Boolean
    Online = InternetGetConnectedState(0&, 0&)
End Function
'判断是否在线并返回连接方式
Public Property Get OnlineOfLinkName(LinkName As String) As Boolean
    LinkName = Space$(128)
    OnlineOfLinkName = InternetGetConnectedStateEx(0, LinkName, 128, 0&)
End Property

'如果是通过LAN的连接,则返回True
Public Function IsNetConnectViaLAN() As Boolean
    Dim dwFlags As Long
    Call InternetGetConnectedState(dwFlags, 0&)
    IsNetConnectViaLAN = dwFlags And INTERNET_CONNECTION_LAN
End Function
'如果是通过调制解调器的连接,则返回True
Public Function IsNetConnectViaModem() As Boolean
    Dim dwFlags As Long
    Call InternetGetConnectedState(dwFlags, 0&)
    IsNetConnectViaModem = dwFlags And INTERNET_CONNECTION_MODEM
End Function
'如果是通过Proxy代理服务器的连接,则返回True
Public Function IsNetConnectViaProxy() As Boolean
    Dim dwFlags As Long
    Call InternetGetConnectedState(dwFlags, 0&)
    IsNetConnectViaProxy = dwFlags And INTERNET_CONNECTION_PROXY
End Function
'如果已安装了RAS,则返回True
Public Function IsNetRASInstalled() As Boolean
    Dim dwFlags As Long
    Call InternetGetConnectedState(dwFlags, 0&)
    IsNetRASInstalled = dwFlags And INTERNET_RAS_INSTALLED
End Function
'返回当前网络状态信息字符串
Public Function GetNetConnectString() As String
    Dim dwFlags As Long
    Dim msg As String
    If InternetGetConnectedState(dwFlags, 0&) Then
        If dwFlags And INTERNET_CONNECTION_CONFIGURED Then
            msg = msg & "系统配置了网络连接" & vbCrLf
        End If
        If dwFlags And INTERNET_CONNECTION_LAN Then
            msg = msg & "系统通过局域网与因特网相连接"
        End If
        If dwFlags And INTERNET_CONNECTION_PROXY Then
            msg = msg & "并使用了Proxy代理服务"
        Else: msg = msg & "."
        End If
        If dwFlags And INTERNET_CONNECTION_MODEM Then
            msg = msg & "系统使用调制解调器与因特网相连接"
        End If
        If dwFlags And INTERNET_CONNECTION_OFFLINE Then
            msg = msg & "系统当前处于离线状态"
        End If
        If dwFlags And INTERNET_CONNECTION_MODEM_BUSY Then
            msg = msg & "系统的调制解调器未连接到因特网"
        End If
        If dwFlags And INTERNET_RAS_INSTALLED Then
            msg = msg & "本系统安装了远程访问服务"
        End If
    Else
        msg = "当前未与因特网相连"
    End If
    GetNetConnectString = msg
End Function


 


 

 
相关文章
     没有手动相关文章
 
评论
     查看或发表更多的评论,请单击这里。
 
 
 
 
 
   
  Access911.net   |   a9BBS   |   OTaA System   |
建站日期:2000年4月2日  |  设计施工:陈格 ( access911 & cg1 )
 Copyright © 2000 - 2003 COMET, 陈格 保留所有权利