Access911.net   |   a9BBS   |   OTaA System  
  搜索文章:  
Access911欢迎您光临  
   主页      上传      繁體版       论坛     
设为首页  |  加入收藏   
  
你现在的位置:文章索引 -> 文章分类 -> VBA  
 首页|  近日更新|  下载  |  文章索引  |  搜索|  术语|  承接工程|  
 
系统正在加载内容,请耐心等待...
 
 查询
 窗体
 报表
 
 
 VBA
 函数
 ADO/DAO/ADO.NET
 API
 ADP
 安全
 发布
 OA
 ASP/ASP.NET
 其他语言
 控件
 DELPHI
 C#/.Net
 本站
 其他
 小例程
 常用软件
 参考文档
 业主作品
 网友大作
 
 
友情链接
 access911.net
 
访问人次
 1702138
 
站长 E-Mail
 net911@sina.com
 access911@gmail.com
 
RSS 订阅

显示附加信息 >>>

集合类 :VBA集合对象的安全包装

作者:未详  摘自:未详  :cg1  更新日期:2005-3-13  浏览人次:

 

集合类 :VBA集合对象的安全包装
你迟早都要管理一组由VBA类模块创建的自定义对象,VBA Collection对象是实现这一目的的理想工具。我们在该杂志的Premiere期刊中曾经介绍过Collections,并且阐述了如何使用Collection对象来存储其他对象。虽然该项技术十分有用,但它确实还存在一些局限。在本文中,我们讨论了这些局限,并向你展示如何通过使用(你猜是什么)类模块来克服这些局限。

Collections中遇到的麻烦

Collections 对象中到底有什么问题呢?它似乎存储对象存储得非常好。事实上,它工作起来的确是太好了。Collections对象得最大问题是它可以存储到任何数据类型得引用,例如Integer, String, Long, Variant, 等 (见图1)。

当然,如果你能保证每个对象都具有相同得类型,并且具有相同得属性何方法的话,那么在Collection中处理对象就变得异常简单。例如,作为本月范例Excel VBA项目的组成部分,我们创建一个自定义的File类来代表一个磁盘文件。这个File类有几个属性,其中包括P ath, Size, 和 ShortName。如果你创建了一个File对象的Collection,那么你将希望这个Collection中的每个对象都具有这些属性。你可以毫无异议地使用与下面类似的代码:

' Print the size of the first file in the Collection.
Debug.Print colFiles.Item(1).Size

但是,如果colFiles Collection 中的第一个对象不是File,将会出现什么情况呢?如果它是一个Form 或 Control对象,又会怎样呢?如果它根本就不是一个对象呢?当然,当它试图执行该代码的时候,VBA将生成运行时间错误。


图片如下:
按此在新窗口浏览图片
图1 (左)VBA Collection对象可以容纳任何类型的对象

 
图片如下:
按此在新窗口浏览图片
图2(右) 创建一个Collection类来防止不想要的对象进入集合

输入Collection类

Collection 类 可以充当Collection对象的过滤器,限制你可以在里面存储的对象类型(如图2所示)。通过与你的应用程序中的Collection类(二不是Collection对象本身)的互相作用,你可以防止不想要的对象的进入。创建和使用Collection类允许你扩展Collection对象的属性和方法(后面我们将举例说明)。

为了说明Collection类以及如何创建一个Collection类,我们将使用带有通过扫描磁盘目录创建的文件集合的Excel 97项目。图3显示了一个表单,它用你选择了路径之后存储在自定义Collection类中的文件信息使得列表框通俗化。

这个表单使用一个叫做Files 的Collection类来通俗化列表框。在创建Collection的时候,以向你的VBA项目添加一个新的类模块作为开始,然后在这个新模块的声明段声明一个Private Collection对象。下面是来自Files类模块的声明:

' Collection of files.
Private pcolFiles As New Collection

为了将Collection对象与外界"隔绝",并阻止程序的其他部分用无用的东西填充它,必须将Collection对象声明为Private 。

复制所需要的方法

当然,一旦你已经将Collection 对象声明为Private,那么对于任何过程都没有办法向其中添加项目或从中删除项目了。因而,下一步就是复制Collection对象的标准方法了。尽管听起来象是做了大量额外的工作,实际上仍然在做我们前面所提及的"过滤"工作。

请记住,内建的Collection对象具有Add方法,该方法接受对象引用和独特的、包括文字与数字的标识符。如果你的应用程序正在直接使用Collection对象,那么它将极有可能创建对象的一个新的实例,并将其添加到Collection本身。

' Create a new instance of an object.
Dim objFile As New File
objFile.Path = "C:\AUTOEXEC.BAT"

' Add to a Collection object.
colFiles.Add objFile, objFile.ShortName

应用Collection类,应用程序调用该类的Add方法,传递任何必需的信息。请将先前的代码与Files类的Add方法做一比较:

With a Collection class, the application calls the Add method of the class, passing any required information. Contrast the previous code with the Add method of the Files class:

Public Function Add(Path As String) As File

Dim objFile As File

' Create the new File object.
Set objFile = New File
objFile.Path = Path

' Add it to the Private collection.
pcolFiles.Add objFile, objFile.ShortName

' Return a pointer to the new object.
Set Add = objFile

End Function

在本例中,到Collection的对象创建和添加发生在Add方法内部;而类则保留了完整的控制。任何必需的信息(例如文件的路径)是作为参数向方法提供的。由应用程序调用将文件添加到Collection的代码然后可以简化为:

' Add a file to the collection.
colFiles.Add "C:\AUTOEXEC.BAT"
In addition to the Add method, the Collection class should also implement the Item and Remove methods, as well as a Count property:

Public Function Item(Key As Variant) As File
' Return an item in the collection.
Set Item = pcolFiles.Item(Key)
End Function

Public Sub Remove(Key As Variant)
' Remove an item from the collection.
pcolFiles.Remove Key
End Sub

Property Get Count() As Long
' Return the number of items.
Count = pcolFiles.Count
End Property

请注意,在这三种方法中,我们省略了错误处理--有些事情你是从来都不应该做的!至少应该包括一个错误处理器,通过使用Err对象的Raise方法来将错误传递、给调用过程。


图3 这个表单通过显示文件信息来说明Collection类

' Private variable to store path.
Private pstrPath As String

Property Get Path() As String
' Return stored path value.
Path = pstrPath
End Property

Property Let Path(strPath As String)

Dim strFile As String

' Clear the collection.
Set pcolFiles = New Collection

' Make sure there's a backslash.
If Right(strPath, 1) <> "\" Then
strPath = strPath & "\"
End If

' Get the first file.
strFile = Dir(strPath & "*.*", _
vbReadOnly Or vbHidden Or vbArchive Or vbSystem)
Do Until Len(strFile) = 0
' Add it to the collection.
Call Add(strPath & strFile) 
' Get the next file.
strFile = Dir()
Loop

' Save the path.
pstrPath = strPath

End Property

图4 向Collection类添加Path属性。将该属性和类设置为扫描目录并将所找到的每个文件添加到私有Collection对象。

扩展Collection类

现在,你可以通过声明Files类的一个实例来使用它了,并为曾经由Dir函数找到的每个文件反复调用该类的Add方法。但这不是我们的例子要完成的工作。为什么不是呢?使用Collection类的一个优点是你可以通过添加更多的属性和方法来扩展它的功能;不仅仅限于Add, Remove, Item, 和 Count。

在我们的Files类的情形中,它难道不对在类本身,而不是使用该类的每个应用程序里面,放置扫描目录的代码做更多的检测吗?这是面向对象设计的一个指导原则:将代码放在最靠近需要它的地方。

为了阐述这个概念,我们向Collection类添加了一个Path属性。当你设置这个属性的时候,这个类将对目录进行扫描,并向Collection对象添加它所找到的每个文件(见图4)。

当一个过程改变该类的Path属性的时候,将触发Property Let过程。在我们的例子中,它发生在你从浏览器对话框选择了一个路径之后。这里是完成用文件列表填充Collection任务的简单代码。

' Reinitialize the collection.
Set mobjFiles = New Files

' Set the path property.
mobjFiles.Path = strPath

一旦设置了Path属性,Files类就将通俗化它自己的Collection,并且使它可以提供给应用程序。这已经是另一个例子了,在这个例子里面,过程的"guts"存在于类自己内部(你可以证明类已不再需要它的Add 和Remove方法了。在有些应用程序中,可能确实是这样,但为了达到说明的目的,我们已经选择了留下它们作为该类的一部分)。

一些不利之处

使用VBA Collection类的生活并不总是美酒和玫瑰。当你使用Collection类代替Collection对象时,必须放弃两样东西。第一样是Collection对象的默认方法,Item。默认的方法允许你从你的代码中省略单词"Item"。例如,如下两条语句是一样的,都是假定colFiles引用一个Collection对象。

Debug.Print colFiles.Item(1).Size
Debug.Print colFiles(1).Size

除非你正在使用的是Visual Basic 5.0,否则没有办法为一个类指定默认的方法。因而,你必须总是显式调用Item方法。

Collection类的第二个主要的不足之处是不能创建列举函数。列举类就是可以使For Each循环工作的类。如果你想重复Collection 中的每一个项目,那么就必须用老式的方法来完成,也就是使用Count属性和For Next循环。例如,下面的代码可以通俗化列表框:

' Fill the list box with info.
lstFiles.Clear
For lngCount = 1 To mobjFiles.Count
With mobjFiles.Item(lngCount)
lstFiles.AddItem .ShortName & _
Space(12 - Len(.ShortName)) & _
vbTab & .AttributeString & _
vbTab & .Size
End With
Next

请注意该过程是如何使用计数器变量lngCount来完成从1到Collection中项目数的循环的。With语句使用了Item方法来引用Collection中的每个对象。

请注意,Visual Basic 5.0用户可以通过创建列举函数来克服这一局限。在Visual Basic Book Online中搜索关键字"enumeration"可以得到更为详细的信息。

将来的考验

Collection类的用途是十分广泛的。它不仅可以生成精美的Collection(当它们被别人使用时尤为重要),而且通过添加其他的属性和方法,你可以创建功能特别强大的类。在以后的刊物中,我们将向你展示使用Collection类的更多例子。

本文中所引用的文章可以从网址为http://www.informant.com/mod/modnewupl.htm.的Informant Web下载,文件名:MOD9711MG.ZIP。


Ken Getz和Mike Gilbert是MCW Technologies的高级顾问,他们研究的重点是Visual Basi和Offic及BackOffice组的。他们最近完成了VBA Developer's Handbook and Access 97 Developer's Handbook(VBA开发者手册和Access 97开发者手册)两本书(与Paul Litwin合作),都是由SYBEX出版的。


原文地址:http://www.microsoft.com/china/MSDN/library/archives/technic/develop/vb/0125d.asp

 

 
相关文章
     没有手动相关文章
 
评论
     查看或发表更多的评论,请单击这里。
 
 
 
 
 
   
  Access911.net   |   a9BBS   |   OTaA System   |
建站日期:2000年4月2日  |  设计施工:陈格 ( access911 & cg1 )
 Copyright © 2000 - 2003 COMET, 陈格 保留所有权利