Access911.net   |   a9BBS   |   OTaA System  
  搜索文章:  
Access911欢迎您光临  
   主页      上传      繁體版       论坛     
设为首页  |  加入收藏   
  
你现在的位置:文章索引 -> 文章分类 -> 函数  
 首页|  近日更新|  下载  |  文章索引  |  搜索|  术语|  承接工程|  
 
系统正在加载内容,请耐心等待...
 
 查询
 窗体
 报表
 
 
 VBA
 函数
 ADO/DAO/ADO.NET
 API
 ADP
 安全
 发布
 OA
 ASP/ASP.NET
 其他语言
 控件
 DELPHI
 C#/.Net
 本站
 其他
 小例程
 常用软件
 参考文档
 业主作品
 网友大作
 
 
友情链接
 access911.net
 
访问人次
 1701930
 
站长 E-Mail
 net911@sina.com
 access911@gmail.com
 
RSS 订阅

显示附加信息 >>>

如何求一条记录上几个字段间的标准差?

作者:cg1  摘自:access911.net  :cg1  更新日期:2007-3-16  浏览人次:

 

问题:

我有一个表,里面有几个字段,类似以下格式

id f1 f2 f3 f4
 1  1  2  3  4
 2  4  5  6  7

要在字段 f4 右面再加一列,计算 1 2 3 4 的标准差,就 EXCEL 的 StDev() 函数那样。
图片如下:
按此在新窗口浏览图片

如何在 Access 查询中实现?

 


方法一:

Access 不是 Excel 不要把 EXCEL 工作表的开发方式用到 ACCESS 中来。ACCESS 中比较合适的方法是将数据结构改为

id  GroupID FID FValue
 1        1   1      1
 2        1   2      2
 3        1   3      3
 4        1   4      4
 5        2   1      4
 6        2   2      5
 7        2   3      6
 8        2   4      7

然后用域函数 DStDev 进行统计即可

 

方法二:

如果你不想或者不能更改数据结构,也可以直接调用 EXCEL 的函数来进行计算。方法已经在

    Access 如何调用 Excel 函数《函数》
    http://access911.net/index.asp?u1=a&u2=76FAB11E17DC

    新手来看:Excel新手问题:在VBA 里面如何使用工作表函数?《OA》
    http://access911.net/index.asp?u1=a&u2=72FAB31E12DCE6F3

一文中详细介绍过了,这里就不再重复了

 

方法三:

本文问题只涉及到一条记录,因此完全可以用 JET SQL 的 SELECT 查询解决。更多程度上,其实这算是一个数学统计学问题,而不是编程问题。让我们先来看看 StDev 样本标准差的数学公式:
图片如下:
按此在新窗口浏览图片

如果在字段数确定的情况下,我们完全可以直接写数据公式来完成计算

标准差 = (((f1 - (f1 + f2 + f3 + f4) / 4) ^ 2 + (f2 - (f1 + f2 + f3 + f4) / 4) ^ 2 + (f3 - (f1 + f2 + f3 + f4) / 4) ^ 2 + (f4 - (f1 + f2 + f3 + f4) / 4) ^ 2) / (4 - 1)) ^ 0.5

转换为 JET SQL 代码为:
select *, (((f1 - (f1 + f2 + f3 + f4) / 4) ^ 2 + (f2 - (f1 + f2 + f3 + f4) / 4) ^ 2 + (f3 - (f1 + f2 + f3 + f4) / 4) ^ 2 + (f4 - (f1 + f2 + f3 + f4) / 4) ^ 2) / (4 - 1)) ^ 0.5 as FStDev from tblStDev

结果如下:
图片如下:
按此在新窗口浏览图片


那么如果字段数不确定呢? VBA 支持参数不固定的自定义函数,因此只要用 ParamArray 关键字创建一个参数数量不固定的函数即可。代码及实例如下:

Function Test()
'请将光标停留在这里并按 F5 键运行
    Debug.Print cgStDev1(1, 2, 3, 4)
    Debug.Print cgStDev2(Split("1,2,3,4", ","))
    Debug.Print cgStDev3(1, 2, 3, 4)
    
End Function


'===========================================================
' 过程及函数名:  cgStDev1
' 版本号      :  1.0
' 说明        :  本函数作用:根据固定的4个参数,计算出该参数
'                 的样本标准差。
'                 优点:可以满足本示例,而且计算速度快
'                 缺点:参数数量固定,无法通用
' 引用        :
' 输入参数    :  4个参数,表示样本数值
' 输出值      :  Double
' 返回值      :  --
' 调用演示    :  cgStDev1 1,2,3,4
'                 (或请直接看 test 过程。)
' 最后修改日期:  2007-03-16 14:22:00
' 示例地址    :  http://access911.net/?kbid;72FABE1E14DCECF3
' 作者        :  cg1
' 网站        :  http://access911.net
' 电子邮件    :  access911@gmail.com
' 版权        :  作者保留一切权力,
'                 请在公布本代码时将本段说明一起公布,谢谢!
'===========================================================

Function cgStDev1(ByVal f1 As Double, _
                    ByVal f2 As Double, _
                    ByVal f3 As Double, _
                    ByVal f4 As Double) As Double
    cgStDev1 = (((f1 - (f1 + f2 + f3 + f4) / 4) ^ 2 + (f2 - (f1 + f2 + f3 + f4) / 4) ^ 2 + (f3 - (f1 + f2 + f3 + f4) / 4) ^ 2 + (f4 - (f1 + f2 + f3 + f4) / 4) ^ 2) / (4 - 1)) ^ 0.5
  
End Function

'===========================================================
' 过程及函数名:  cgStDev2
' 版本号      :  1.0
' 说明        :  本函数作用:根据传入的数组变量计算出该参数
'                 的样本标准差。
'                 优点:参数数量不固定
'                 缺点:无法直接在 SQL 语句中调用字段名
'                 若不符合条件则打印出错条件后直接退出函数
' 引用        :
' 输入参数    :  数组变量
' 输出值      :  Double
' 返回值      :  --
' 调用演示    :  cgStDev2(split("1,2,3,4",","))
'                 (或请直接看 test 过程。)
' 最后修改日期:  2007-03-16 14:22:00
' 示例地址    :  http://access911.net/?kbid;72FABE1E14DCECF3
' 作者        :  cg1
' 网站        :  http://access911.net
' 电子邮件    :  access911@gmail.com
' 版权        :  作者保留一切权力,
'                 请在公布本代码时将本段说明一起公布,谢谢!
'===========================================================

Function cgStDev2(ByVal arrF As Variant) As Double
    Dim n As Long
    Dim xBar As Double
    Dim xSigema As Double
    
    Dim i As Long
    
    '求样本数量
    If IsArray(arrF) = True Then
        n = UBound(arrF)
    Else
        Debug.Print "not array"
        Exit Function
    End If
    n = n + 1   '因为默认数组是从 0 开始的,所以要 +1 才是统计学上的n
    If n = 1 Then
        '如果只有一个数字无法计算样本标准差
        Debug.Print "#DIV/0!"
        Exit Function
    End If
    
    '求样本平均值
    For i = 1 To n
        xBar = xBar + arrF(i - 1)
    Next
    xBar = xBar / n
    
    'Debug.Print xBar
    
    '求分母
    For i = 1 To n
        xSigema = xSigema + (arrF(i - 1) - xBar) ^ 2
    Next

    cgStDev2 = (xSigema / (n - 1)) ^ 0.5
End Function


'===========================================================
' 过程及函数名:  cgStDev3
' 版本号      :  1.0
' 说明        :  本函数作用:根据传入的不确定数量的参数计算
'                 样本标准差。
'                 优点:参数数量不固定,可直接在 SQL 中使用
'                 缺点:效率不高
'                 若不符合条件则打印出错条件后直接退出函数
' 引用        :
' 输入参数    :  数组参数
' 输出值      :  Double
' 返回值      :  --
' 调用演示    :  cgStDev3(1,2,3,4)
'                 (或请直接看 test 过程。)
' 最后修改日期:  2007-03-16 14:22:00
' 示例地址    :  http://access911.net/?kbid;72FABE1E14DCECF3
' 作者        :  cg1
' 网站        :  http://access911.net
' 电子邮件    :  access911@gmail.com
' 版权        :  作者保留一切权力,
'                 请在公布本代码时将本段说明一起公布,谢谢!
'===========================================================

Function cgStDev3(ParamArray Items()) As Double
    Dim n As Long
    Dim xBar As Double
    Dim xSigema As Double
    
    Dim i As Long
    
    '求样本数量
    If IsArray(Items) = True Then
        n = UBound(Items)
    Else
        Debug.Print "not array"
        Exit Function
    End If
    n = n + 1   '因为默认数组是从 0 开始的,所以要 +1 才是统计学上的n
    If n = 1 Then
        '如果只有一个数字无法计算样本标准差
        Debug.Print "#DIV/0!"
        Exit Function
    End If
    
    '求样本平均值
    For i = 1 To n
        xBar = xBar + Items(i - 1)
    Next
    xBar = xBar / n
    
    'Debug.Print xBar
    
    '求分母

    For i = 1 To n
        xSigema = xSigema + (Items(i - 1) - xBar) ^ 2
    Next

    cgStDev3 = (xSigema / (n - 1)) ^ 0.5
End Function


示例下载:
http://access911.net/down/eg/eg_StDev.rar
 (22KB)


注意:上述只是实现该功能的算法,并不是最优算法,哪位算法高手可以帮忙再优化一下。如果还能优化提高计算速度请在本文“评论”中回复一下,谢谢!

以上方法都代表一种思路,并不只适用于求标准差一件事情,请大家举一反三地应用。
其实这个问题很简单,根本不需要大费周张,就是所谓的“计算列”问题。看看我03年的一篇文章,今天的问题只是那篇文章的再应用而已。
    新手来看:设计表的时候怎么定义计算列? 
    http://access911.net/?kbid;74FAB01E13DC
 

 


本站文章旨在为该问题提供解决思路及关键性代码,并不能完成应该由网友自己完成的所有工作,请网友在仔细看文章并理解思路的基础上举一反三、灵活运用。

access911.net 原创文章,作者本人对文章保留一切权利。
如需转载必须征得作者同意并注明本站链接


 

 
相关文章
     没有手动相关文章
 
评论
     查看或发表更多的评论,请单击这里。
 
 
 
 
 
   
  Access911.net   |   a9BBS   |   OTaA System   |
建站日期:2000年4月2日  |  设计施工:陈格 ( access911 & cg1 )
 Copyright © 2000 - 2003 COMET, 陈格 保留所有权利